Type classes to assist random generation of values for various types of abstract data types.

How to use ToADTArbitrary with Generic.

{-# LANGUAGE DeriveGeneric #-}

import Data.Proxy
import GHC.Generics
import Test.QuickCheck
import Test.QuickCheck.Arbitrary.ADT

-- Sum Type, multiple constructors with parameters
data Fruit
  = Apple Int
  | Orange String Int
  | PassionFruit Int String Int
  deriving (Generic, Show)

-- Product Type, single constructor
data Person =
  Person
    { name :: String
    , age  :: Int
    } deriving (Generic, Show)

Any type that implements ToADTArbitrary must also implement Arbitrary. These examples all require that the data type is an instance of Generic.

instance Arbitrary Fruit where
  arbitrary = genericArbitrary

instance ToADTArbitrary Fruit

instance Arbitrary Person where
  arbitrary = genericArbitrary

instance ToADTArbitrary Person

Now we can use toADTArbitrarySingleton to produce an arbitrary value of one random constructor along with some metadata. toADTArbitrary will produce an arbitrary value for each constructor and return it along with a String of the constructor name.

λ> generate (toADTArbitrarySingleton (Proxy :: Proxy Fruit))
ADTArbitrarySingleton {
  adtasModuleName = "Ghci1"
, adtasTypeName = "Fruit"
, adtasCAP = ConstructorArbitraryPair {
    capConstructor = "Apple", capArbitrary = Apple 30}}

λ> generate (toADTArbitrary (Proxy :: Proxy Fruit))
ADTArbitrary {
  adtModuleName = "Ghci1"
, adtTypeName = "Fruit"
, adtCAPs = [
    ConstructorArbitraryPair {
        capConstructor = "Apple"
      , capArbitrary = Apple 17}
  , ConstructorArbitraryPair {
        capConstructor = "Orange"
      , capArbitrary = Orange "abcdef" 18}
  , ConstructorArbitraryPair {
        capConstructor = "PassionFruit"
      , capArbitrary = PassionFruit 16 "datadata" 6}]}

λ> generate (toADTArbitrarySingleton (Proxy :: Proxy Person))
ADTArbitrarySingleton {
  adtasModuleName = "Ghci1"
, adtasTypeName = "Person"
, adtasCAP = ConstructorArbitraryPair {capConstructor = "Person", capArbitrary = Person {name = "John Doe", age = 30}}}

λ> generate (toADTArbitrary (Proxy :: Proxy Person))
ADTArbitrary {
  adtModuleName = "Ghci1"
, adtTypeName = "Person"
, adtCAPs = [ConstructorArbitraryPair {capConstructor = "Person", capArbitrary = Person {name = "Jane Doe", age = 15}}]}