Documentation

An error-catching version of holds that returns False in case of errors.

prop_cannot_be_seven :: Int -> Bool
prop_cannot_be_seven 7  =  error "Argument cannot be seven"
prop_cannot_be_seven _  =  True

> import Test.LeanCheck
> holds 100 prop_cannot_be_seven
*** Exception: Argument cannot be seven

> import Test.LeanCheck.Error
> holds 100 prop_cannot_be_seven
False

An error-catching version of fails that returns True in case of errors.

An error-catching version of exists.

An error-catching version of counterExample.

An error-catching version of counterExamples.

An error-catching version of witness.

An error-catching version of witnesses.

An error-catching version of results.

Transforms errors into a default value.

> fromError 0 (15 :: Int)
15

> fromError 0 (undefined :: Int)
0

Transforms a value into Just that value or Nothing on some errors:

• ArithException
• ArrayException
• ErrorCall
• PatternMatchFail

> errorToNothing False
Just False

> errorToNothing (0 :: Int)
Just 0

> errorToNothing (undefined :: ())
Nothing

This function uses unsafePerformIO.

Transforms errors into False values.

> errorToFalse False
False

> errorToFalse True
True

> errorToFalse undefined
False

This functions uses unsafePerformIO.

Transforms errors into True values.

> errorToTrue False
False

> errorToTrue True
True

> errorToTrue undefined
True

This functions uses unsafePerformIO.

Transforms a value into Right that value or 'Left String' on some errors:

• ArithException
• ArrayException
• ErrorCall
• PatternMatchFail

> errorToLeft False
Just False

> errorToLeft (0 :: Int)
Just 0

> errorToLeft (undefined :: ())
Left "Prelude.undefined"

> errorToLeft (error "error message")
Left "error message"

> errorToLeft (1 `div` 0 :: Int)
Left "divide by zero"

Only the first line of the error's string representation is included.

This function uses unsafePerformIO.

Transforms a value into Just that value or Nothing on error.

Transforms a value into Right that value or 'Left String' on error.

Only the first line of the error's string representation is included.

This function uses unsafePerformIO. See: errorToLeft.

Equality == lifted over errorToNothing

> 1 `div` 1  ?==?  2 `div` 2
True

> 1 `div` 1  ?==?  1 `div` 2
False

> 1 `div` 1  ?==?  1 `div` 0
False

> 6 `mod` 0  ?==?  2 `div` 0
True

> head []  ?==?  tail []
True

> error "a"  ?==?  error "a"
True

> error "a"  ?==?  error "b"
True

This function consider error values equal.

Equality == lifted over errorToLeft

> 1 `div` 1  !==!  2 `div` 2
True

> 1 `div` 1  !==!  1 `div` 2
False

> 1 `div` 1  !==!  1 `div` 0
False

> 6 `mod` 0  !==!  2 `div` 0
True

> head []  !==!  tail []
False

> error "a"  !==!  error "a"
True

> error "a"  !==!  error "b"
False

On error, this function returns the result of comparing the first line of error values.

A type is Listable when there exists a function that is able to list (ideally all of) its values.

Ideally, instances should be defined by a tiers function that returns a (potentially infinite) list of finite sub-lists (tiers): the first sub-list contains elements of size 0, the second sub-list contains elements of size 1 and so on. Size here is defined by the implementor of the type-class instance.

For algebraic data types, the general form for tiers is

tiers  =  cons<N> ConstructorA
       \/ cons<N> ConstructorB
       \/ ...
       \/ cons<N> ConstructorZ

where N is the number of arguments of each constructor A...Z.

Here is a datatype with 4 constructors and its listable instance:

data MyType  =  MyConsA
             |  MyConsB Int
             |  MyConsC Int Char
             |  MyConsD String

instance Listable MyType where
  tiers =  cons0 MyConsA
        \/ cons1 MyConsB
        \/ cons2 MyConsC
        \/ cons1 MyConsD

The instance for Hutton's Razor is given by:

data Expr  =  Val Int
           |  Add Expr Expr

instance Listable Expr where
  tiers  =  cons1 Val
         \/ cons2 Add

Instances can be alternatively defined by list. In this case, each sub-list in tiers is a singleton list (each succeeding element of list has +1 size).

The function deriveListable from Test.LeanCheck.Derive can automatically derive instances of this typeclass.

A Listable instance for functions is also available but is not exported by default. Import Test.LeanCheck.Function if you need to test higher-order properties.

Testable values are functions of Listable arguments that return boolean values.

•  Bool

•  Listable a => a -> Bool

•  (Listable a, Listable b) => a -> b -> Bool

•  (Listable a, Listable b, Listable c) => a -> b -> c -> Bool

•  (Listable a, Listable b, Listable c, ...) => a -> b -> c -> ... -> Bool

For example:

•  Int -> Bool

•  String -> [Int] -> Bool

(cf. results)

Boolean implication operator. Useful for defining conditional properties:

prop_something x y  =  condition x y ==> something x y

Examples:

> prop_addMonotonic x y  =  y > 0 ==> x + y > x
> check prop_addMonotonic
+++ OK, passed 200 tests.

Resets any delays in a list-of tiers. Conceptually this function makes a constructor "weightless", assuring the first tier is non-empty.

reset [[], [], ..., xs, ys, zs, ...]  =  [xs, ys, zs, ...]

reset [[], xs, ys, zs, ...]  =  [xs, ys, zs, ...]

reset [[], [], ..., [x], [y], [z], ...]  =  [[x], [y], [z], ...]

Typically used when defining Listable instances:

instance Listable <Type> where
  tiers  =  ...
         \/ reset (cons<N> <Constructor>)
         \/ ...

Be careful: do not apply reset to recursive data structure constructors. In general this will make the list of size 0 infinite, breaking the tiers invariant (each tier must be finite).

Checks a property printing results on stdout

> check $ \xs -> sort (sort xs) == sort (xs::[Int])
+++ OK, passed 200 tests.

> check $ \xs ys -> xs `union` ys == ys `union` (xs::[Int])
*** Failed! Falsifiable (after 4 tests):
[] [0,0]

Check a property for a given number of tests printing results on stdout

> checkFor 1000 $ \xs -> sort (sort xs) == sort (xs::[Int])
+++ OK, passed 1000 tests.

Test exhaustion is reported when the configured number of tests is larger than the number of available test values:

> checkFor 3 $ \p -> p == not (not p)
+++ OK, passed 2 tests (exhausted).

Check a property printing results on stdout and returning True on success.

> p <- checkResult $ \xs -> sort (sort xs) == sort (xs::[Int])
+++ OK, passed 200 tests.

> q <- checkResult $ \xs ys -> xs `union` ys == ys `union` (xs::[Int])
*** Failed! Falsifiable (after 4 tests):
[] [0,0]

> p && q
False

There is no option to silence this function: for silence, you should use holds.

Check a property for a given number of tests printing results on stdout and returning True on success.

> checkResultFor 1000 $ \xs -> sort (sort xs) == sort (xs::[Int])
+++ OK, passed 1000 tests.
True

There is no option to silence this function: for silence, you should use holds.

Given a constructor with no arguments, returns tiers of all possible applications of this constructor.

Since in this case there is only one possible application (to no arguments), only a single value, of size/weight 0, will be present in the resulting list of tiers.

To be used in the declaration of tiers in Listable instances.

instance Listable <Type> where
  tiers  =  ...
         \/ cons0 <Constructor>
         \/ ...

Given a constructor with one Listable argument, return tiers of applications of this constructor.

By default, returned values will have size/weight of 1.

To be used in the declaration of tiers in Listable instances.

instance Listable <Type> where
  tiers  =  ...
         \/ cons1 <Constructor>
         \/ ...

Given a constructor with two Listable arguments, return tiers of applications of this constructor.

By default, returned values will have size/weight of 1.

To be used in the declaration of tiers in Listable instances.

instance Listable <Type> where
  tiers  =  ...
         \/ cons2 <Constructor>
         \/ ...

Returns tiers of applications of a 3-argument constructor.

To be used in the declaration of tiers in Listable instances.

instance Listable <Type> where
  tiers  =  ...
         \/ cons3 <Constructor>
         \/ ...

Returns tiers of applications of a 4-argument constructor.

To be used in the declaration of tiers in Listable instances.

Returns tiers of applications of a 5-argument constructor.

To be used in the declaration of tiers in Listable instances.

Returns tiers of applications of a 6-argument constructor.

Returns tiers of applications of a 7-argument constructor.

Returns tiers of applications of a 8-argument constructor.

Returns tiers of applications of a 9-argument constructor.

Returns tiers of applications of a 10-argument constructor.

Returns tiers of applications of a 11-argument constructor.

Returns tiers of applications of a 12-argument constructor.

Delays the enumeration of tiers. Conceptually this function adds to the weight of a constructor.

delay [xs, ys, zs, ... ]  =  [[], xs, ys, zs, ...]

delay [[x,...], [y,...], ...]  =  [[], [x,...], [y,...], ...]

Typically used when defining Listable instances:

instance Listable <Type> where
  tiers  =  ...
         \/ delay (cons<N> <Constructor>)
         \/ ...

Resets the weight of a constructor or tiers.

> [ [], [], ..., xs, ys, zs, ... ] `ofWeight` 1
[ [], xs, ys, zs, ... ]

> [ xs, ys, zs, ... ] `ofWeight` 2
[ [], [], xs, ys, zs, ... ]

> [ [], xs, ys, zs, ... ] `ofWeight` 3
[ [], [], [], xs, ys, zs, ... ]

Typically used as an infix operator when defining Listable instances:

instance Listable <Type> where
  tiers  =  ...
         \/ cons<N> <Cons>  `ofWeight`  <W>
         \/ ...

Warning: do not apply `ofWeight` 0 to recursive data structure constructors. In general this will make the list of size 0 infinite, breaking the tier invariant (each tier must be finite).

`ofWeight` n is equivalent to reset followed by n applications of delay.

Adds to the weight of a constructor or tiers.

instance Listable <Type> where
  tiers  =  ...
         \/ cons<N> <Cons>  `addWeight`  <W>
         \/ ...

Typically used as an infix operator when defining Listable instances:

> [ xs, ys, zs, ... ] `addWeight` 1
[ [], xs, ys, zs, ... ]

> [ xs, ys, zs, ... ] `addWeight` 2
[ [], [], xs, ys, zs, ... ]

> [ [], xs, ys, zs, ... ] `addWeight` 3
[ [], [], [], [], xs, ys, zs, ... ]

`addWeight` n is equivalent to n applications of delay.

Tiers of values that follow a property.

Typically used in the definition of Listable tiers:

instance Listable <Type> where
  tiers  =  ...
         \/ cons<N> `suchThat` <condition>
         \/ ...

Examples:

> tiers `suchThat` odd
[[], [1], [-1], [], [], [3], [-3], [], [], [5], ...]

> tiers `suchThat` even
[[0], [], [], [2], [-2], [], [], [4], [-4], [], ...]

This function is just a flipped version of filterT.

Append tiers --- sum of two tiers enumerations.

[xs,ys,zs,...] \/ [as,bs,cs,...]  =  [xs++as, ys++bs, zs++cs, ...]

Interleave tiers --- sum of two tiers enumerations. When in doubt, use \/ instead.

[xs,ys,zs,...] \/ [as,bs,cs,...]  =  [xs+|as, ys+|bs, zs+|cs, ...]

Take a tiered product of lists of tiers.

[t0,t1,t2,...] >< [u0,u1,u2,...]  =
  [ t0**u0
  , t0**u1 ++ t1**u0
  , t0**u2 ++ t1**u1 ++ t2**u0
  , ...       ...       ...       ...
  ]
  where
  xs ** ys  =  [(x,y) | x <- xs, y <- ys]

Example:

[[0],[1],[2],...] >< [[0],[1],[2],...]  =
  [ [(0,0)]
  , [(1,0),(0,1)]
  , [(2,0),(1,1),(0,2)]
  , [(3,0),(2,1),(1,2),(0,3)]
  , ...
  ]

(cf. productWith)

Take a tiered product of lists of tiers. productWith can be defined by ><, as:

productWith f xss yss  =  map (uncurry f) $ xss >< yss

(cf. ><)

map over tiers

mapT f [[x], [y,z], [w,...], ...]  =  [[f x], [f y, f z], [f w, ...], ...]

mapT f [xs, ys, zs, ...]  =  [map f xs, map f ys, map f zs]

filter tiers

filterT p [xs, yz, zs, ...]  =  [filter p xs, filter p ys, filter p zs]

filterT odd tiers  =  [[], [1], [-1], [], [], [3], [-3], [], [], [5], ...]

concat tiers of tiers

concatT [ [xss0, yss0, zss0, ...]
        , [xss1, yss1, zss1, ...]
        , [xss2, yss2, zss2, ...]
        , ...
        ]
  =  xss0 \/ yss0 \/ zss0 \/ ...
          \/ delay (xss1 \/ yss1 \/ zss1 \/ ...
                         \/ delay (xss2 \/ yss2 \/ zss2 \/ ...
                                        \/ (delay ...)))

(cf. concatMapT)

concatMap over tiers

concatMapT f [ [x0, y0, z0]
             , [x1, y1, z1]
             , [x2, y2, z2]
             , ...
             ]
  =  f x0 \/ f y0 \/ f z0 \/ ...
          \/ delay (f x1 \/ f y1 \/ f z1 \/ ...
                         \/ delay (f x2 \/ f y2 \/ f z2 \/ ...
                                        \/ (delay ...)))

(cf. concatT)

Delete the first occurence of an element in a tier.

For normalized lists-of-tiers without repetitions, the following holds:

deleteT x  =  normalizeT . (`suchThat` (/= x))

Normalizes tiers by removing up to 12 empty tiers from the end of a list of tiers.

normalizeT [xs0,xs1,...,xsN,[]]     =  [xs0,xs1,...,xsN]
normalizeT [xs0,xs1,...,xsN,[],[]]  =  [xs0,xs1,...,xsN]

The arbitrary limit of 12 tiers is necessary as this function would loop if there is an infinite trail of empty tiers.

Takes a list of values xs and transform it into tiers on which each tier is occupied by a single element from xs.

toTiers [x, y, z, ...]  =  [[x], [y], [z], ...]

To convert back to a list, just concat.

Derives a Listable instance for a given type Name.

Consider the following Stack datatype:

data Stack a  =  Stack a (Stack a) | Empty

Writing

deriveListable ''Stack

will automatically derive the following Listable instance:

instance Listable a => Listable (Stack a) where
  tiers  =  cons2 Stack \/ cons0 Empty

Warning: if the values in your type need to follow a data invariant, the derived instance won't respect it. Use this only on "free" datatypes.

Needs the TemplateHaskell extension.

Derives a Listable instance for a given type Name cascading derivation of type arguments as well.

Consider the following series of datatypes:

data Position  =  CEO | Manager | Programmer

data Person  =  Person
             {  name :: String
             ,  age :: Int
             ,  position :: Position
             }

data Company  =  Company
              {  name :: String
              ,  employees :: [Person]
              }

Writing

deriveListableCascading ''Company

will automatically derive the following three Listable instances:

instance Listable Position where
  tiers  =  cons0 CEO \/ cons0 Manager \/ cons0 Programmer

instance Listable Person where
  tiers  =  cons3 Person

instance Listable Company where
  tiers  =  cons2 Company

Given a constructor that takes a set of elements (as a list), lists tiers of applications of this constructor.

A naive Listable instance for the Set (of Data.Set) would read:

instance Listable a => Listable (Set a) where
  tiers  =  cons0 empty \/ cons2 insert

The above instance has a problem: it generates repeated sets. A more efficient implementation that does not repeat sets is given by:

  tiers  =  setCons fromList

Alternatively, you can use setsOf direclty.

Given a constructor that takes a bag of elements (as a list), lists tiers of applications of this constructor.

For example, a Bag represented as a list.

bagCons Bag

Given a constructor that takes a list with no duplicate elements, return tiers of applications of this constructor.

Given a constructor that takes a map of elements (encoded as a list), lists tiers of applications of this constructor

So long as the underlying Listable enumerations have no repetitions, this will generate no repetitions.

This allows defining an efficient implementation of tiers that does not repeat maps given by:

  tiers  =  mapCons fromList

Like productWith, but over 3 lists of tiers.

Take the product of lists of tiers by a function returning a Maybe value discarding Nothing values.

Takes as argument tiers of element values; returns tiers of lists of elements.

listsOf [[]]  =  [[[]]]

listsOf [[x]]  =  [ [[]]
                  , [[x]]
                  , [[x,x]]
                  , [[x,x,x]]
                  , ...
                  ]

listsOf [[x],[y]]  =  [ [[]]
                      , [[x]]
                      , [[x,x],[y]]
                      , [[x,x,x],[x,y],[y,x]]
                      , ...
                      ]

Takes as argument tiers of element values; returns tiers of size-ordered lists of elements without repetition.

setsOf [[0],[1],[2],...] =
  [ [[]]
  , [[0]]
  , [[1]]
  , [[0,1],[2]]
  , [[0,2],[3]]
  , [[0,3],[1,2],[4]]
  , [[0,1,2],[0,4],[1,3],[5]]
  , ...
  ]

Can be used in the constructor of specialized Listable instances. For Set (from Data.Set), we would have:

instance Listable a => Listable (Set a) where
  tiers  =  mapT fromList $ setsOf tiers

Takes as argument tiers of element values; returns tiers of size-ordered lists of elements possibly with repetition.

bagsOf [[0],[1],[2],...] =
  [ [[]]
  , [[0]]
  , [[0,0],[1]]
  , [[0,0,0],[0,1],[2]]
  , [[0,0,0,0],[0,0,1],[0,2],[1,1],[3]]
  , [[0,0,0,0,0],[0,0,0,1],[0,0,2],[0,1,1],[0,3],[1,2],[4]]
  , ...
  ]

Takes as argument tiers of element values; returns tiers of lists with no repeated elements.

noDupListsOf [[0],[1],[2],...] ==
  [ [[]]
  , [[0]]
  , [[1]]
  , [[0,1],[1,0],[2]]
  , [[0,2],[2,0],[3]]
  , ...
  ]

Takes the product of N lists of tiers, producing lists of length N.

Alternatively, takes as argument a list of lists of tiers of elements; returns lists combining elements of each list of tiers.

products [xss]  =  mapT (:[]) xss
products [xss,yss]  =  mapT (\(x,y) -> [x,y]) (xss >< yss)
products [xss,yss,zss]  =  product3With (\x y z -> [x,y,z]) xss yss zss

Takes as argument an integer length and tiers of element values; returns tiers of lists of element values of the given length.

listsOfLength 3 [[0],[1],[2],[3],[4]...] =
  [ [[0,0,0]]
  , [[0,0,1],[0,1,0],[1,0,0]]
  , [[0,0,2],[0,1,1],[0,2,0],[1,0,1],[1,1,0],[2,0,0]]
  , ...
  ]

Tiers of Floating values. This can be used as the implementation of tiers for Floating types.

This function is equivalent to tiersFractional with positive and negative infinities included: 10 and -10.

NaN and -0 are excluded from this enumeration.

This function is deprecated. Please consider using listFloating instead or use toTiers listFloating.

Tiers of Fractional values. This can be used as the implementation of tiers for Fractional types.

This function is deprecated. Please consider using listFractional instead or use toTiers listFractional.

Listing of Floating values. This can be used as the implementation of list for Floating types.

listFloating :: [Double]  =
  [0.0, 1.0, -1.0, 0.5, -0.5, 2.0, Infinity, -Infinity, -2.0, 0.333, ...]

This follow the same Calkin-Wilf sequence of listFractional but positive and negative infinities are artificially included after two.

NaN and -0 are excluded from this enumeration.

Listing of Fractional values. This can be used as the implementation of list for Fractional types.

listFractional :: [[Rational]]  =
  [0 % 1, 1 % 1, (-1) % 1, 1 % 2, (-1) % 2, 2 % 1, (-2) % 1, 1 % 3, ...]

All rationals are included without repetition in their most simple form. This is the Calkin-Wilf sequence computed with the help of the fusc function (EWD 570).

This also works for unsigned types that wrap around zero, yielding:

listFractional :: [Ratio Word]  =
  [0 % 1, 1 % 1, 1 % 2, 2 % 1, 1 % 3, 3 % 2, 2 % 3, 3 % 1, 1 % 4, ...]

Tiers of Integral values. Can be used as a default implementation of list for Integral types.

For types with negative values, like Int, the list starts with 0 then intercalates between positives and negatives.

listIntegral  =  [0, 1, -1, 2, -2, 3, -3, 4, -4, ...]

For types without negative values, like Word, the list starts with 0 followed by positives of increasing magnitude.

listIntegral  =  [0, 1, 2, 3, 4, 5, 6, 7, 8, 9, ...]

This function will not work for types that throw errors when the result of an arithmetic operation is negative such as Natural. For these, use [0..] as the list implementation.

Lazily interleaves two lists, switching between elements of the two. Union/sum of the elements in the lists.

[x,y,z,...] +| [a,b,c,...]  =  [x,a,y,b,z,c,...]