Dynamically dispatched effects.

A dynamically dispatched effect is a collection of operations that can be interpreted in different ways at runtime, depending on the handler that is used to run the effect.

This allows a programmer to separate the what from the how, i.e. define effects that model what the code should do, while providing handlers that determine how it should do it later. Moreover, different environments can use different handlers to change the behavior of specific parts of the application if appropriate.

Let's create an effect for basic file access, i.e. writing and reading files.

First, we need to define a generalized algebraic data type of kind Effect, where each constructor corresponds to a specific operation of the effect in question.

>>> :{
  data FileSystem :: Effect where
    ReadFile  :: FilePath -> FileSystem m String
    WriteFile :: FilePath -> String -> FileSystem m ()
:}

>>> type instance DispatchOf FileSystem = Dynamic

The FileSystem effect has two operations:

• ReadFile, which takes a FilePath and returns a String in the monadic context.
• WriteFile, which takes a FilePath, a String and returns a () in the monadic context.

For people familiar with mtl style effects, note that the syntax looks very similar to defining an appropriate type class:

class FileSystem m where
  readFile  :: FilePath -> m String
  writeFile :: FilePath -> String -> m ()

The biggest difference between these two is that the definition of a type class gives us operations as functions, while the definition of an effect gives us operations as data constructors. They can be turned into functions with the help of send:

>>> :{
  readFile :: (HasCallStack, FileSystem :> es) => FilePath -> Eff es String
  readFile path = send (ReadFile path)
:}

>>> :{
  writeFile :: (HasCallStack, FileSystem :> es) => FilePath -> String -> Eff es ()
  writeFile path content = send (WriteFile path content)
:}

Note: the above functions and the DispatchOf instance can also be automatically generated by the makeEffect function from the effectful-th package.

The following defines an EffectHandler that reads and writes files from the drive:

>>> import Effectful.Error.Static
>>> import Effectful.Exception
>>> import System.IO qualified as IO

>>> newtype FsError = FsError String deriving Show

>>> :{
 runFileSystemIO
   :: (IOE :> es, Error FsError :> es)
   => Eff (FileSystem : es) a
   -> Eff es a
 runFileSystemIO = interpret $ \_ -> \case
   ReadFile path           -> adapt $ IO.readFile path
   WriteFile path contents -> adapt $ IO.writeFile path contents
   where
     adapt m = liftIO m `catchIO` \e -> throwError . FsError $ show e
:}

Here, we use interpret and simply execute corresponding IO actions for each operation, additionally doing a bit of error management.

On the other hand, maybe there is a situation in which instead of interacting with the outside world, a pure, in-memory storage is preferred:

>>> import Data.Map.Strict qualified as M
>>> import Effectful.State.Static.Local

>>> :{
  runFileSystemPure
    :: Error FsError :> es
    => M.Map FilePath String
    -> Eff (FileSystem : es) a
    -> Eff es a
  runFileSystemPure fs0 = reinterpret (evalState fs0) $ \_ -> \case
    ReadFile path -> gets (M.lookup path) >>= \case
      Just contents -> pure contents
      Nothing       -> throwError . FsError $ "File not found: " ++ show path
    WriteFile path contents -> modify $ M.insert path contents
:}

Here, we use reinterpret and introduce a State effect for the storage that is private to the effect handler and cannot be accessed outside of it.

Let's compare how these differ.

>>> :{
  action = do
    file <- readFile "effectful-core.cabal"
    pure $ length file > 0
:}

>>> :t action
action :: (FileSystem :> es) => Eff es Bool

>>> runEff . runError @FsError . runFileSystemIO $ action
Right True

>>> runPureEff . runErrorNoCallStack @FsError . runFileSystemPure M.empty $ action
Left (FsError "File not found: \"effectful-core.cabal\"")

Note that the definition of the FileSystem effect from the previous section doesn't use the m type parameter. What is more, when the effect is interpreted, the LocalEnv argument of the EffectHandler is also not used. Such effects are first order.

If an effect makes use of the m parameter, it is a higher order effect.

Note: for handling first order effects you can use interpret_ or reinterpret_ whose EffectHandler_ doesn't take the LocalEnv parameter.

Interpretation of higher order effects is slightly more involving. To see why, let's consider the Profiling effect for logging how much time a specific action took to run:

>>> :{
  data Profiling :: Effect where
    Profile :: String -> m a -> Profiling m a
:}

>>> type instance DispatchOf Profiling = Dynamic

>>> :{
  profile :: (HasCallStack, Profiling :> es) => String -> Eff es a -> Eff es a
  profile label action = send (Profile label action)
:}

If we naively try to interpret it, we will run into trouble:

>>> import GHC.Clock (getMonotonicTime)

>>> :{
 runProfiling :: IOE :> es => Eff (Profiling : es) a -> Eff es a
 runProfiling = interpret $ \_ -> \case
   Profile label action -> do
     t1 <- liftIO getMonotonicTime
     r <- action
     t2 <- liftIO getMonotonicTime
     liftIO . putStrLn $ "Action '" ++ label ++ "' took " ++ show (t2 - t1) ++ " seconds."
     pure r
:}
...
... Couldn't match type ‘localEs’ with ‘es’
...

The problem is that action has a type Eff localEs a, while the monad of the effect handler is Eff es. localEs represents the local environment in which the Profile operation was called, which is opaque as the effect handler cannot possibly know how it looks like.

The solution is to use the LocalEnv that an EffectHandler is given to run the action using one of the functions from the localUnlift family:

>>> :{
 runProfiling :: IOE :> es => Eff (Profiling : es) a -> Eff es a
 runProfiling = interpret $ \env -> \case
   Profile label action -> localSeqUnliftIO env $ \unlift -> do
     t1 <- getMonotonicTime
     r <- unlift action
     t2 <- getMonotonicTime
     putStrLn $ "Action '" ++ label ++ "' took " ++ show (t2 - t1) ++ " seconds."
     pure r
:}

In a similar way we can define a dummy interpreter that does no profiling:

>>> :{
 runNoProfiling :: Eff (Profiling : es) a -> Eff es a
 runNoProfiling = interpret $ \env -> \case
   Profile label action -> localSeqUnlift env $ \unlift -> unlift action
:}

...and it's done.

>>> action = profile "greet" . liftIO $ putStrLn "Hello!"

>>> :t action
action :: (Profiling :> es, IOE :> es) => Eff es ()

>>> runEff . runProfiling $ action
Hello!
Action 'greet' took ... seconds.

>>> runEff . runNoProfiling $ action
Hello!

There exists a lot of libraries that provide their functionality as an mtl style effect, which generally speaking is a type class that contains core operations of the library in question.

Such effects are quite easy to use with the Eff monad. As an example, consider the mtl style effect for generation of random numbers:

>>> :{
  class Monad m => MonadRNG m where
    randomInt :: m Int
:}

Let's say the library also defines a helper function for generation of random strings:

>>> import Control.Monad
>>> import Data.Char

>>> :{
 randomString :: MonadRNG m => Int -> m String
 randomString n = map chr <$> replicateM n randomInt
:}

To make it possible to use it with the Eff monad, the first step is to create an effect with operations that mirror the ones of a type class:

>>> :{
  data RNG :: Effect where
    RandomInt :: RNG m Int
:}

>>> type instance DispatchOf RNG = Dynamic

If we continued as in the example above, we'd now create top level helper functions that execute effect operations using send, in this case randomInt tied to RandomInt. But this function is already declared by the MonadRNG type class! Therefore, what we do instead is provide an orphan, canonical instance of MonadRNG for Eff that delegates to the RNG effect:

>>> :set -XUndecidableInstances

>>> :{
  instance RNG :> es => MonadRNG (Eff es) where
    randomInt = send RandomInt
:}

Now we only need an interpreter:

>>> :{
  runDummyRNG :: Eff (RNG : es) a -> Eff es a
  runDummyRNG = interpret_ $ \case
    RandomInt -> pure 55
:}

and we can use any function that requires a MonadRNG constraint with the Eff monad as long as the RNG effect is in place:

>>> runEff . runDummyRNG $ randomString 3
"777"

For dealing with classes that employ functional dependencies an additional trick is needed.

Consider the following:

>>> :set -XFunctionalDependencies

>>> :{
  class Monad m => MonadInput i m | m -> i where
    input :: m i
:}

An attempt to define the instance as in the example above leads to violation of the liberal coverage condition:

>>> :{
  instance Reader i :> es => MonadInput i (Eff es) where
    input = ask
:}
...
...Illegal instance declaration for ‘MonadInput i (Eff es)’...
...  The liberal coverage condition fails in class ‘MonadInput’...
...    for functional dependency: ‘m -> i’...
...

However, there exists a trick for bypassing the coverage condition, i.e. including the instance head in its context:

>>> :{
  instance (MonadInput i (Eff es), Reader i :> es) => MonadInput i (Eff es) where
    input = ask
:}

Now the MonadInput class can be used with the Eff monad:

>>> :{
  double :: MonadInput Int m => m Int
  double = (+) <$> input <*> input
:}

>>> runPureEff . runReader @Int 3 $ double
6