This is a Haskell port of the Hashids library by Ivan Akimov. This is not a cryptographic hashing algorithm. Hashids is typically used to encode numbers to a format suitable to appear in places like urls.

See the official Hashids home page: http://hashids.org

Hashids is a small open-source library that generates short, unique, non-sequential ids from numbers. It converts numbers like 347 into strings like yr8, or a list of numbers like [27, 986] into 3kTMd. You can also decode those ids back. This is useful in bundling several parameters into one or simply using them as short UIDs.

Note that most of the examples on this page require the OverloadedStrings extension.

Unless you require a minimum length for the generated hash, create a context using hashidsSimple and then call encode and decode with this object.

{-# LANGUAGE OverloadedStrings #-}

import Web.Hashids

main :: IO ()
main = do
    let context = hashidsSimple "oldsaltyswedishseadog"
    print $ encode context 42

This program will output

"kg"

To specify a minimum hash length, use hashidsMinimum instead.

main = do
    let context = hashidsMinimum "oldsaltyswedishseadog" 12
    print $ encode context 42

The output will now be

"W3xbdkgdy42v"

If you only need the context once, you can use one of the provided wrappers to simplify things.

main :: IO ()
main = print $ encodeUsingSalt "oldsaltyswedishseadog" 42

On the other hand, if your implementation invokes the hashing algorithm frequently without changing the configuration, it is probably better to define partially applied versions of encode, encodeList, and decode.

import Web.Hashids

context :: HashidsContext
context = createHashidsContext "oldsaltyswedishseadog" 12 "abcdefghijklmnopqrstuvwxyz"

encode'     = encode context
encodeList' = encodeList context
decode'     = decode context

main :: IO ()
main = print $ encode' 12345

Use a custom alphabet and createHashidsContext if you want to make your hashes "unique".

main = do
    let context = createHashidsContext "oldsaltyswedishseadog" 0 "XbrNfdylm5qtnP19R"
    print $ encode context 1

The output is now

"Rd"

To encode a list of numbers, use encodeList.

let context = hashidsSimple "this is my salt" in encodeList context [0, 1, 2]

"yJUWHx"

Decoding a hash returns a list of numbers,

let context = hashidsSimple "this is my salt"
     hash = decode context "rD"        -- == [5]

Decoding will not work if the salt is changed:

main = do
    let context = hashidsSimple "this is my salt"
        hash = encode context 5

    print $ decodeUsingSalt "this is my pepper" hash

When decoding fails, the empty list is returned.

[]

Hashids is based on a modified version of the Fisher-Yates shuffle. The primary purpose is to obfuscate ids, and it is not meant for security purposes or compression. Having said that, the algorithm does try to make hashes unguessable and unpredictable. See the official Hashids home page for details: http://hashids.org

let context = hashidsSimple "this is my salt" in encodeList context $ replicate 4 5

There are no repeating patterns in the hash to suggest that four identical numbers are used:

"1Wc8cwcE"

The same is true for increasing numbers:

let context = hashidsSimple "this is my salt" in encodeList context [1..10]

"kRHnurhptKcjIDTWC3sx"

let context = hashidsSimple "this is my salt" in map (encode context) [1..5]

["NV","6m","yD","2l","rD"]

The algorithm tries to avoid generating common curse words in English by never placing the following letters next to each other:

c, C, s, S, f, F, h, H, u, U, i, I, t, T