{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE QuasiQuotes       #-}
{-# LANGUAGE TemplateHaskell   #-}

{-| A copy of "Logging.Monad.TH"
-}

module Logging.Global.TH
  ( logv
  , debug
  , info
  , warn
  , error
  , fatal
  ) where

import           Control.Monad.IO.Class  (MonadIO)
import           Data.Aeson
import           Language.Haskell.TH
import           Prelude                 hiding (error, log)

import           Logging.Class
import           Logging.Global.Internal
import           Logging.Level
import           Logging.Logger

-- | Log "message" with the severity "level".
--
-- The missing type signature:
-- ('MonadIO' m, 'IsMessage' s) => 'Logger' -> 'Level' -> s -> m ()
logv :: ExpQ
logv = do
  loc <- location
  let filename = loc_filename loc
      packagename = loc_package loc
      modulename = loc_module loc
      lineno = fst $ loc_start loc
      location = (filename, packagename, modulename, lineno)
  [| \logger level msg -> log logger level msg Null location |]

-- | Log "message" with a specific severity.
--
-- The missing type signature:
-- ('MonadIO' m, 'IsMessage' s) => 'Logger' -> s -> m ()
debug, info, warn, error, fatal :: ExpQ
debug = [| \logger -> $(logv) logger $ read "DEBUG" |]
info  = [| \logger -> $(logv) logger $ read "INFO" |]
warn  = [| \logger -> $(logv) logger $ read "WARN" |]
error = [| \logger -> $(logv) logger $ read "ERROR" |]
fatal = [| \logger -> $(logv) logger $ read "FATAL" |]