-- | SuperCollider 'UGen' database.
--
-- The database is generated by an @sclang@ program and is given by
-- the constant value 'ugenDB', which is a list of 'U' entries.
--
-- > length ugenDB == 391
module Sound.SC3.UGen.DB where

import Data.Char
import Sound.SC3.UGen.DB.Data

-- | Lookup 'U' at 'ugenDB'.
--
-- > fmap ugen_default_rate (uLookup "SinOsc") == Just Sound.SC3.AR
uLookup :: String -> Maybe U
uLookup nm = lookup nm (zip (map ugen_name ugenDB) ugenDB)

-- | Case-insensitive variant of 'uLookup'.
--
-- > fmap ugen_default_rate (uLookup_ci "fft") == Just Sound.SC3.KR
uLookup_ci :: String -> Maybe U
uLookup_ci nm =
    let lc = map toLower
        db_nm = map (lc . ugen_name) ugenDB
    in lookup (lc nm) (zip db_nm ugenDB)

-- | Pretty printer for 'I'.
--
-- > iPP (I {input_name = "freq", input_default = 440.0}) == "freq=440.0"
iPP :: I -> String
iPP i = input_name i ++ "=" ++ show (input_default i)

-- | Lookup named 'UGen' and generate simple summary string.  If the
-- /fold case/ flag is true the name lookup is case insensitive.
ugenSummary' :: Bool -> String -> String
ugenSummary' fc nm =
    let r = if fc then uLookup_ci nm else uLookup nm
    in case r of
         Just u -> unwords [ugen_name u
                           ,show (ugen_operating_rates u)
                           ,unwords (map iPP (ugen_inputs u))]
         Nothing -> error "unknown UGen?"

-- | Lookup named 'UGen' and generate simple summary string.
--
-- > ugenSummary "SinOsc" == "SinOsc [AR,KR] freq=440.0 phase=0.0"
ugenSummary :: String -> String
ugenSummary = ugenSummary' False

-- | Case-insensitive variant of 'ugenSummary'.
--
-- > ugenSummary_ci "fSinOsc" == "FSinOsc [AR,KR] freq=440.0 iphase=0.0"
ugenSummary_ci :: String -> String
ugenSummary_ci = ugenSummary' True